PkUnknown Class

<SerializableAttribute>
Public Class PkUnknown
	Inherits Packet

[SerializableAttribute]
public class PkUnknown : Packet

Imports RRAutoLib.Loconet

Public Class PkCustom
    Inherits PkUnknown

    Public Sub New()
        'initialize an n byte packet;
        'in this example it is a 4 byte OPS_LOCO_ADR
        _bytaBytes = New Byte(3) {&HBF, 0, 0, 0}
    End Sub

    Public Sub New(address As UShort)
        'simplify class construction
        Me.New()
        Me.Address = address
    End Sub

    Public Property Address() As UShort
        Get
            'decode parameter from packet bytes
            Dim bits = BitWise.CopyBits(_bytaBytes(3), 0, 7, 0, 0)  'least significant 7 bits
            Return BitWise.CopyBits(_bytaBytes(2), 0, 7, bits, 7)   'most significant 7 bits
        End Get
        Set(value As UShort)
            'encode parameter to packet bytes
            BitWise.CopyBits(value, 0, 7, _bytaBytes(3), 0)     'least significant 7 bits
            BitWise.CopyBits(value, 7, 7, _bytaBytes(2), 0)     'most significant 7 bits
        End Set
    End Property

    Public Overrides ReadOnly Property NeedsPacketResponse() As Boolean
        Get
            'indicates that this packet expects a response
            Return True
        End Get
    End Property

    Public Overrides Function ValidPacketResponse(responsePacket As RRAutoLib.Loconet.Packet) As Boolean
        'indicates that this packet expects either a slot read or a long aknoledge as a response packet    
        Return responsePacket.OpCode = OpCodes.SL_RD_DATA OrElse _
               responsePacket.OpCode = OpCodes.LONG_ACK
    End Function

    Public Overrides ReadOnly Property Description() As String
        Get
            'brief description of packet
            Return "My custom packet"
        End Get
    End Property

    Public Overrides ReadOnly Property ParmsDesc() As String
        Get
            'description of decoded packet parameters
            Return $"Adr={Me.Address}"
        End Get
    End Property

End Class